Asymetrix Multimedia Toolbook 4.0 (CBT Edition)/Asymetric Multimedia Toolbook 4.0 (CBT Edition).iso/ctb40mt.z/DBASE.ATS

Text File | 1995-11-13 | 11KB | 400 lines

ACTION    "Link TB40DB3.DLL"
BEHAVIOR    "Links to the functions in TB40DB3.DLL."
CATEGORIES    dBaseIII
{
    sysSuspend = FALSE
    clear sysError
    linkdll sysToolBookDirectory & "tb40DB3.DLL"
        INT checkDBIndex(STRING)
        INT closeAllDBFiles()
        INT closeDBFile(STRING)
        INT closeDBIndexFile(STRING)
        WORD createDBFieldTag(WORD)
        INT createDBFile(STRING,WORD,WORD)
            INT createDBIndexFile(STRING,STRING,WORD,WORD)
        INT deleteDBFile(STRING)
        INT deselectDBIndexFile()
        INT findDBKey(STRING)
        INT firstDBKey()
        INT firstDBRecord()
        INT freeDBFieldTag(WORD)
        STRING getDBDateFormat()
        STRING getDBErrorString(INT)
        INT getDBFieldCount()
        STRING getDBFieldName(WORD)
        INT getDBFieldPrecision(STRING)
        INT getDBFieldType(STRING)
        STRING getDBFieldValue(STRING)
        INT getDBFieldWidth(STRING)
        STRING getDBFileName()
        STRING getDBIndexExpression()
        STRING getDBIndexFileName()
        INT getDBKeyType()
        STRING getDBKeyValue()
        INT getDBNavigateToDeleted()
        LONG getDBRecordCount()
        INT getDBRecordDeleted()
        LONG getDBRecordNumber()
        INT gotoDBRecord(DWORD)
        INT lastDBKey()
        INT lastDBRecord()
        INT nextDBKey()
        INT nextDBRecord()
        INT openDBFile(STRING)
        INT openDBIndexFile(STRING)
        INT packDBFile()
        INT previousDBKey()
        INT previousDBRecord()
        INT reindexDBFile(STRING)
        INT removeDBRecords(DWORD,DWORD)
        INT selectDBFile(STRING)
        INT selectDBIndexFile(STRING)
        INT setDBDateFormat(STRING)
        INT setDBFieldTag(WORD,WORD,STRING,STRING,WORD,WORD)
        INT setDBFieldValue(STRING, STRING)
        INT setDBNavigateToDeleted(INT)
        INT setDBRecordDeleted(WORD)
        INT writeDBRecord(DWORD)
    end linkdll
     if sysError <> null
        request "Could not link to TB40db3.dll"
    end    if
}

SCRIPT "Create a dbf file."
BEHAVIOR "An example of the code needed to create a dBaseIII file."
CATEGORIES    dBaseIII
{
to handle createDB3
-- this is an example, most dbf files must be custom tailored.
    set fileName to "mydata.dbf"

-- We create a template that each record will use.
-- Names, number, widths, and types of the fields all
-- must be carefully synchronized
    set fNames to "firstName,lastName,employeeID," & \
      "birthDate,insurance,comments"
    set fNumber to itemCount(fNames)

-- "C" is character, "N" is numeric, "D" is date,
-- "L" is logical, and "M" is memo.
    set fTypes to "C,C,N,D,L,M"

-- Date, logical and memo do not require widths.
    set fWidths to "14,14,10,0,0,0"

-- Now we allocate a structure and get a "tag number" for it.
    set tagNumber to createDBFieldTag(fNumber)
    if tagNumber <> 0

-- Now we use the tag for the structure and the data for the fields
-- to tell the DLL what the records will look like.
        step i from 1 to fNumber
            get setDBFieldTag(tagNumber, i, item i of fNames, \
              item i of fTypes, item i of fWidths, 0)
            if it <= 0
                request getDBErrorString(it)
                break
            end if
        end step
    else
        request "CreateDBFieldTag failure"
        break
    end if

-- Now we actually create the .dbf file that knows about this kind of record.
-- The last parameter allows ToolBook to write over an
-- existing file. "1" would prevent this.
    get createDBFile(fileName,tagNumber,0)
    if it <= 0
        request getDBErrorString(it)
        break
    end if
    get freeDBFieldTag(tagNumber)
    get closeDBFile(fileName)
end createDB3
}

SCRIPT "Create a dBase index"
BEHAVIOR "An example for creating an index for a .dbf file."
CATEGORIES    dBaseIII
{
to handle createDB3Index
    set fileName to "myData.ndx"

-- The art of designing a good index is in setting the
-- key expression correctly.
    set myExpression to "lastName+firstName"

-- The index is created using the currently selected dBase file.
    get createDBIndexFile(fileName,myExpression,0,0)
    if it < 1
        request getDBErrorString(it)
    end    if
end createDB3Index
}

SCRIPT "Search for a string in DBIII"
BEHAVIOR "An example for using an index to search a .dbf file."
CATEGORIES    dBaseIII
{
-- Simple wrapper for findDBKey. Provides some feedback to the user for two
-- special cases. FindDBKey returns 3 if it can't find the text, and returns 4
-- if the search text goes past the last key.
to handle findKey searchString
    get findDBKey(searchString)
    conditions
    when it = 3
        request "String not found, next key becomes the current key."
    when it = 4
        request "String greater than last key, last key becomes the current key."
        -- belt and suspenders
        get lastDBKey()
    when it < 1
        request getDBErrorString(it)
    end    conditions
end    findKey
}

SCRIPT "Get the current key"
BEHAVIOR "An example for getting the value of the current key of an index for a .dbf file."
CATEGORIES    dBaseIII
{
-- Simple wrapper for getDBKeyValue
to get keyValue
    return getDBKeyValue()
end    keyValue
}

SCRIPT "Get the total record count"
BEHAVIOR "An example for finding the total number of records in a .dbf file"
CATEGORIES    dBaseIII
{
-- Simple wrapper for getDBRecordCount
to get totalRecords
    return getDBRecordCount()
end totalRecords
}

SCRIPT "Select a dBIII index"
BEHAVIOR "An example for selecting between open indexes of a .dbf file."
CATEGORIES    dBaseIII
{
-- Wrapper for indexing, handles errors until it gives up.
to set index to value
    -- make sure when you pass the parameter "value"
    -- you include the path

    get checkDBIndex(value)
    if it = 1
        get selectDBIndexFile(value)
    else
        get reindexDBFile(value)
        if it < 1
            get getDBErrorString(it)
        end    if
    end    if
end    index
}

SCRIPT "Navigate in a dBIII Database"
BEHAVIOR "An example for navigation in a dBIII database."
CATEGORIES    dBaseIII
{
-- Simple wrapper for dBase navigation
-- Possible values to pass are:
-- first, last, next, previous, or a valid record number.
-- For example: "set currentRecord to "last""
to set currentRecord to value
    set it to -1

    conditions
    when value = "first"
        get firstDBKey()
    when value = "last"
        get lastDBKey()
    when value = "next"
        get nextDBKey()
    when value = "previous"
        get previousDBKey()
    else
    -- check to see that "value" is valid
        if isType(Real, value) and value > 0
            get goToDBRecord(value)
        end if
    end conditions

    if it < 0
        if getDBRecordDeleted(currentRecord()) = 1    -- calls the "to get currentRecord" function
              request "Record marked as deleted. Shall I" & CRLF & TAB &\
             "Unmark the record for you," & CRLF & TAB &\
             "Leave it marked, but let you navigate to it," & CRLF & TAB &\
             "Or pack the database and delete the record."  \
              with "Unmark" or "Leave Marked" or "Pack and Delete"
            conditions
            when it is "Unmark"
                get setDBRecordDeleted(0) -- undelete
                get goToDBRecord(value)
            when it is "Leave Marked"
            -- remember old value
                set NavToDel to getDBNavigateToDeleted()
            -- get set and go
                get setDBNavigateToDeleted(1)
                get goToDBRecord(value)
            -- reset old value
                get setDBNavigateToDeleted(NavToDel)
            when it is "Pack and Delete"
                sysCursor = 4
                get packDBFile()
                if it < 1
                    request getDBErrorString(it)
                else
            -- some default behavior, nothing but something to do
                    get firstDBKey()
                end if
            end conditions
        else
            request getDBErrorString(it)
        end if
    end if
end currentRecord

-- We need a corresponding "to get" handler, but this is very simple
to get currentRecord
    get getDBRecordNumber()
    if it < 1
        request getDBErrorString(it)
    end if

    -- calling handler would need to check this value to see if
    -- an error has occured.
    return it
end currentRecord
}

SCRIPT "Set the value of a field in dBIII"
BEHAVIOR "An example for setting the value of a field in a .dbf file"
CATEGORIES    dBaseIII
{
-- Simple wrapper for setDBFieldValue,
-- A call to it might look like:
-- "set fieldValue(firstName) to "Jimmy"", or
-- "fieldValue(lastName) = "Carter"".
-- It sets the field in the current    record.
to set fieldValue fieldName to value
    get setDBFieldValue(fieldName, value)
    if it < 0
        request getDBErrorString(it)
    end if
end fieldValue
}

SCRIPT "Get the value of a DBIII field"
BEHAVIOR "An example for getting the value of a field in a .dbf file"
CATEGORIES    dBaseIII
{
-- Simple wrapper for getDBFieldValue
-- typically fieldName would be passed in a to get handler like:
-- "get fieldValue("lastName")", which would return a last name.
to get fieldValue fieldName
    clear sysError
    get getDBFieldValue(fieldName)
    if sysError is not null
        request getDBErrorString(syserror)
    else
        return it
    end if
    return null
end fieldValue
}

SCRIPT "Create a new DBIII record"
BEHAVIOR "An example for creating a new record in a database"
CATEGORIES    dBaseIII
{
-- Creates a new (and empty) record.
to handle newDBRecord
-- We create a new record by writing past the end of the database.
    get writeDBRecord(getDBRecordCount() + 1)
    if it < 0
        request getDBErrorString(it)
    end if
end newDBRecord
}

SCRIPT "Write to a DBIII database"
BEHAVIOR "An example for writing a record out to a .dbf file."
CATEGORIES    dBaseIII
{
-- Simple wrapper for writeDBRecord. This is where the dBase record
-- is actually written out. The handler expects you to pass the
-- record number of the record that is being written, so this would
-- be called like this: "send writeDB getDBRecordNumber()", or with any
-- other value that would evaluate to a record number.
to handle writeDB rNumber
    get writeDBRecord(rNumber)
    if it < 0
        request getDBErrorString(it)
    end if
end writeDB
}

SCRIPT "Delete a dBIII record"
BEHAVIOR "An example for marking and deleting a record from a .dbf file."
CATEGORIES    dBaseIII
{
-- Simple wrapper for setDBRecordDeleted. Note also we pack the dBase here,
-- there's no recovery for a deleted file.
to handle deleteRecord
-- This marks the current record as "deleted"
    get setDBRecordDeleted(1)
    if it < 0
        request getDBErrorString(it)
    end    if

-- You may not want the next line if you want to be able to
-- recover from this operation.    It is possible to undelete a marked record,
-- but not after you have packed the database.
-- Note that this refers to a ToolBook handler, not a DLL function.
    send packDatabase
end deleteRecord
}

SCRIPT "Pack a dBIII File"
BEHAVIOR "An example for packing a dBase file and any associated, open indexes."
CATEGORIES    dBaseIII
{
-- Simple wrapper for packDBFile
to handle packDatabase
    sysCursor = 4
-- Operates on the current dBase
    get packDBFile()
    if it < 1
        request getDBErrorString(it)
    end if
    sysCursor = default
end packDatabase
}

SCRIPT "Turn a ToolBook field into a dBase field"
BEHAVIOR "An appropriately named field can quickly become a window on a DBIII database by placing these handlers in the script of a field, and broadcasting the appropriate messages."
CATEGORIES    dBaseIII
{
-- Get and set data for and from these fields
notifyBefore updateDisplay
    -- this call the "to get fieldValue" function
    -- found under the name of "Get the value of a DBIII field" in tb40.ats
    my text = fieldValue(my name) of this book
end updateDisplay

notifyBefore updateDB
    -- this call the "to set fieldValue" handler
    -- found under the name of "Set the value of a field in DBIII " in tb40.ats
    fieldValue(my name) of this book = my text
end updateDB

notifyBefore clearFields
    clear my text
    fieldValue(my name) of this book = null
end clearFields
}